퀵스타트

렌파이 퀵스타트 매뉴얼에 오신 것을 환영합니다. 이 매뉴얼에는 몇 가지 간단한 단계를 거쳐 렌파이 게임을 처음부터 만드는 법에 대한 내용이 적혀있습니다. 그러기위해 이 매뉴얼은 The Question 이라는 간단한 게임을 어떻게 만드는 지를 처음부터 보여줄 것입니다. 이 매뉴얼은 데모 게임의 일부에 포함된 많은 예제를 포함하고 있습니다.

렌파이 런처

게임을 만들기 전에, 렌파이 런처가 어떤 식으로 작동하는지 익혀보는 시간을 가져봅시다. 런처를 이용하면 렌파이 프로젝트를 생성하고, 관리하고, 수정하고, 구동할 수 있습니다.

시작하기. 렌파이로 게임을 제작하려면 우선 렌파이를 다운로드 하세요.

렌파이를 다운로드 한 후 압축을 푸세요. 일반적으로 압축 파일을 우클릭한 후 "압축 풀기"나 "열기"를 선택해 압축을 풀 수 있습니다. 화면에 나오는 지시사항 대로 따라가다보면 렌파이의 복사본을 얻게 됩니다.

주석

렌파이는 반드시 하드디스크에 있는 폴더나 경로에 압축 해제하세요. zip파일 내부에서 구동하면 제대로 작동하지 않을 것입니다.

렌파이의 압축을 해제했다면 이제 실행해야 합니다.

• Windows에서는, renpy 나 renpy.exe 프로그램을 실행하세요.
• Mac OS X에서는, renpy 어플리케이션을 실행하세요.
• Linux에서는, renpy.sh 스크립트를 실행하세요

그러면 렌파이 런처가 실행될 것입니다.

렌파이 런처는 다양한 언어로 번역되었습니다. 언어를 바꾸려면 "preferences"를 선택하고 원하는 언어를 선택하세요.

프로젝트를 선택하고 구동하기. 미리 완성된 게임인 The Question 이 어떤 모습인지 확인해봅시다. 렌파이 런처를 실행하고 첫 번째 화면에서 "The Question"을 선택하세요. 이제 "프로젝트 실행" 버튼을 눌러 The Question 을 실행할 수 있습니다.

위의 과정 중에 "The Question" 대신에 "길라잡이"를 선택하면 렌파이 데모로 돌아갈 수도 있습니다.

새 프로젝트 생성하기. 런처에서 "새 프로젝트 만들기" 를 선택해 새 프로젝트를 생성하세요. 런처에 프로젝트 이름을 입력하라는 화면이 뜰 것입니다. "The Question"은 이미 사용 중인 이름이기 때문에, "My Question" 같은 다른 이름을 입력해야 합니다. 그 다음에 프로젝트의 색상 테마를 선택해야 합니다. 지금은 어떤 것을 선택하더라도 문제 없으니 끌리는 색상을 선택하세요. 그 후에는 여러분이 만든 게임이 선택된 채로 런처의 메인 메뉴로 돌아오게 될 것입니다.

간단한 게임

label start:
    "나는 그녀에게 물었다..."

    "나" "음... 너..."
    "나" "너 혹시 내 비주얼 노벨의 원화가가 되어줄래?"

    "침묵."
    "그녀는 놀랐다, 그리고..."

    "실비" "물론이지, 근데 \"비주얼 노벨\"이 뭐야?"

이는 아마도 가장 단순한 렌파이 게임일 것입니다. 그림 같은 것이 아무것도 없고 단지 두 인물 간의 대사만 표시합니다.

이 코드를 시험해보려면 런처를 실행해서 "My Question" 프로젝트를 선택하고 파일 수정하기 칸에 있는 "script.rpy" 를 선택하세요. 그러면 런처에서 어떤 스크립트 에디터를 사용할 것인지 묻고, 선택한 에디터를 다운로드할 것입니다. 자운로드를 마치면 script.rpy 파일이 선택한 에디터에서 열립니다. script.rpy 안에 있는 내용은 전부 지우세요. 처음부터 시작하고 있으니 그 안에 있는 내용은 전혀 필요하지 않습니다. 위의 예제를 복사해서 script.rpy 파일에 붙여넣고 저장하세요.

이제 예제를 실행할 준비가 된 것입니다. 런처로 돌아가서 "프로젝트 실행"을 클릭하세요. 렌파이가 시작될 것입니다. 렌파이에는 추가로 스크립트를 입력하지 않아도 세이브, 로드, 환경설정 메뉴가 구현되어 있는 것을 확인하세요. 준비가 됐으면 "프로젝트 실행"버튼을 클릭하시고 예제 게임을 플레이하세요.

이 예제에는 자주 사용되는 렌파이 명령문이 몇 가지 있습니다.

첫 번째 줄은 label 문입니다. label 문은 프로그램에서 특정한 영역에 이름을 정하기 위해 사용됩니다. 이 예제에서는 start 라는 이름의 레이블을 생성했습니다. start 레이블은 특별한 레이블로, 사용자가 메인 메뉴에 있는 "시작하기" 버튼을 클릭했을 때 렌파이 스크립트가 실행되기 시작하는 부분입니다.

다른 행들은 say문이라고 합니다. say문에는 두 가지 형태가 있습니다. 하나는 문자열(따옴표로 시작해서 글자를 포함하고 따옴표로 끝나는 것) 하나만으로 행을 이루는 형태로, 내레이션이나 주인공 캐릭터의 생각을 나타낼 때 사용됩니다. 다른 하나는 두 개의 문자열로 구성되어있습니다. 이 형태는 대사문에 사용되는데, 첫번째 문자열은 캐릭터의 이름이고 두 번째 문자열은 그 캐릭터가 말하고 있는 대사입니다.

모든 say 문은 4개의 스페이스로 들여쓰기가 되었다는 걸 기억하세요. 이는 say문이 label문 속에서 블럭을 이루고 있기 때문입니다. 렌파이에서 블럭들은 이전 명령문에 상대적으로 반드시 들여쓰기가 되어야 하며, 같은 블럭에 있는 모든 명령문은 반드시 똑같은 양만큼 들여쓰기를 해야 합니다.

문자열 안에 큰 따옴표가 있다면, 그 따옴표 앞에는 백슬래시를 써야 합니다. 이것은 예제의 마지막 줄에 사용되었습니다.

이 예제 스크립트에는 살펴볼 내용이 그다지 없습니다. 렌파이에서 동작하는 무언가를 만드는 것이 얼마나 쉬운지를 보여주기 위한 예제이기 때문입니다. 여기에 그림도 조금 추가할 것입니다만 그 전에 먼저 캐릭터를 어떻게 선언하는지 살펴봅시다.

init문

init문은 스크립트가 실행되기 전에 렌파이 명령문 블럭을 실행할 때 사용합니다. init 블럭은 그림과 캐릭터를 정의하거나 변경하지 않을 게임 데이터 구조를 설정하거나, 렌파이를 꾸밀 때 사용합니다. init 블럭 안에 있는 코드는 사용자와 상호작용하거나 어떤 레이어도 변경하지 않아야 하므로 say, menu, scene, show, hide 문을 사용할 수 없으며 이런 명령문과 같은 작동을 하는 함수를 호출할 수 없습니다.

init 문은 init 라는 키워드로 시작하며, 추가적으로 우선도를 나타내는 숫자를 적을 수 있으며, 마지막에 콜론을 꼭 적어야 합니다. 우선도를 지정하지 않으면 기본값음 0입니다. 우선도를 나타낼 숫자의 범위는 -999에서 999까지입니다. 이 범위 외의 숫자는 렌파이 코드가 사용하도록 할당되어 있습니다.

우선도는 init 블럭 안에 있는 코드가 실행되는 순서를 결정할 때 사용합니다. init 블럭은 낮은 값에서 높은 값 순서대로 실행됩니다. 동일한 파인 안에 있는 init 블럭들은 서로 우선도가 동일하다면 위에서 아래 순서대로 실행됩니다. 서로 다른 파일 안에 있고 우선순위가 동일한 init 블럭의 계산 순서는 정의되지 않았습니다.

init 블럭은 특수한 초기화 과정 동안 한 번만 실행됩니다. 제어 흐름이 통상 실행 과정 동안에 init 블럭 끝에 도달하면 해당 블럭의 실행은 종료합니다. 통상 샐항 과정 중에 init 문을 만나면 해당 init 블럭은 실행되지 않습니다. 대신 제어 흐름은 다음 명령문으로 이동합니다.

캐릭터

첫번째 예제에는 대사를 말하는 캐릭터의 이름을 꼬박꼬박 적어야 한다는 문제가 있습니다. 대사가 많은 게임에서는 엄청난 양을 타이핑해야 할지도 모릅니다. 게다가 두 캐릭터의 이름이 똑같이 지겨운 하얀색 글씨로 표시될 것입니다. 이 문제를 해결하려면 캐릭터를 미리 정의해야 합니다. 그렇게 하면 짧은 이름에 캐릭터를 연결할 수 있고, 캐릭터 이름의 색깔도 바꿀 수 있습니다.

define s = Character('실비', color="#c8ffc8")
define m = Character('나', color="#c8c8ff")

label start:
    "나는 그녀에게 물었다..."

    m  "음... 너..."
    m "너 혹시 내 비주얼 노벨의 원화가가 되어줄래"

    "침묵."
    "그녀는 놀랐다, 그리고..."

    s "물론이지, 근데 \"비주얼 노벨\"이 뭐야?"

첫 번째와 두 번째 행에서는 캐릭터를 정의합니다. 첫 번째 행에서는 "실비"의 약칭으로 사용될 "s" 에 캐릭터를 정의했습니다. "실비"라는 이름은 초록빛으로 표시될 것입니다. (색상은 빨강-녹색-파랑의 16진수 3 쌍으로, 웹 상에서 사용되는 것과 같은 것입니다).

두 번째 행에서는 "나"의 약칭으로 사용될 "m"에 캐릭터를 생성했습니다. "나"라는 이름은 붉은색으로 표시될 것입니다. 다른 캐릭터도 이런 식으로 긴 이름, 짧은 이름, 색상 등을 변경해 정의할 수 있습니다.

이 에제에서는 또한 say문에서 캐릭터 이름이 적힌 문자열 대신 캐릭터 객체를 사용하도록 수정했습니다. 이것은 우리가 init 블럭에 정의한 문자를 사용하도록 렌파이에 알려주는 것입니다.

그림

비주얼 노벨에 그림이 없다면 비주얼 노벨이 아닐 것입니다. 게임에 그림을 조금 추가해봅시다.

image bg meadow = "meadow.jpg"
image bg uni = "uni.jpg"

image sylvie smile = "sylvie_smile.png"
image sylvie surprised = "sylvie_surprised.png"

define s = Character('실비', color="#c8ffc8")
define m = Character('나', color="#c8c8ff")

label start:
    scene bg meadow
    show sylvie smile

    "나는 그녀에게 물었다..."

    m  "음... 너..."
    m "너 혹시 내 비주얼 노벨의 원화가가 되어줄래?"

    show sylvie surprised

    "침묵."
    "그녀는 놀랐다, 그리고..."

    show sylvie smile

    s "물론이지, 근데 \"비주얼 노벨\"이 뭐야?"

우리가 해야할 일은 init 블럭에 2, 3, 4, 6 번째 행에 있는 image문을 사용해 이미지를 선언하는 것입니다. 이 image문으로는 이미지 이름을 지정하고, 그 이름에 사용할 그림이 저장된 파일 이름을 지정합니다.

예를 들어 다섯 번째 행은 "sylvie_smile.png" 파일에 있는 이미지를 "sylvie"라는 태그가 붙은 "sylvie smile"라는 이름으로 선언합니다.

12 번째 행에는 scene 문이 있습니다. 이 명령문은 화면을 비우고, "bg meadow"라는 이미지를 표시합니다. 다음 줄에는 show문이 있는데, 이 명령문은 "sylvie smile"이라는 그림을 화면에 표시합니다.

이미지 이름에서 첫 번째 부분은 이미지 태그라고 합니다. 어떤 이미지가 나타나려고 하는데 같은 태그를 가진 이미지가 화면에 있다면, 이미 화면에 있는 이미지는 현재 표시되고 있는 이미지로 바뀌게 될 것입니다. 두 번째 show 문이 적힌 19번째 행에서 이런 현상이 발생합니다. 19번째 행이 실행되기 전에는 "sylvie smile"이라는 이미지가 화면에 있습니다. 그러나 19번째 행이 실행되면 그 이미지는 "sylvie surprised"라는 이미지로 교체됩니다. 그 두 이미지는 "sylvie" 라는 태그를 사용하고 있기 때문입니다.

그림파일이 렌파이에서 인식되려면, 그림 파일들을 현재 프로젝트의 game 디렉토리에 두어야 합니다. game 디렉토리는 "프로젝트 이름/game/" 경로에서 발견할 수 있고, 런처에 있는 "Game Directory"를 누르면 찾을 수 있습니다. 이 예제를 실행하고 싶다면 "the_question/game/" 디렉토리에 있는 그림 파일들을 "my_question/game/" 로 복사해야 합니다.

렌파이는 캐릭터 이미지와 배경 그림 이미지를 구별하지 않습니다. 그 둘을 똑같은 이미지의 한 종류로 취급하기 때문입니다. 즉 캐릭터 이미지가 정상 표시되려면 투명도가 있어야 하므로 PNG 파일이어야 할 것입니다. 배경그림은 JPEG나 PNG 파일이어야 할 것입니다. 배경화면 그림은 "bg" 태그로 시작하는 것이 관례입니다.

Hide 문. 렌파이는 그림을 숨기는 hide문도 지원합니다.

label leaving:

    s "지금 당장 시작해야지!"

    hide sylvie

    "..."

    m "이게 아닌데."

사실 hide문을 사용할 필요는 그다지 없을 것입니다. 캐릭터의 표정을 바꿀 때는 show문을, 모든 캐릭터가 화면에서 사라지는 때에는 scene문이 사용하면 되기 때문입니다. hide는 한 캐릭터가 같은 장면 내에서 사라지게 할 때에만 사용하면 됩니다.

트랜지션

단순히 그림을 팟 하고 나타냈다가 사라진다면 재미가 없을 것입니다. 그래서 렌파이는 화면을 좀 더 흥미롭게 바꾸도록 하는 트랜지션을 구현합니다. 트랜지션을 사용하면 이전 인터렉션 (대사, 선택지 혹은 트랜지션)이 종료했을 때의 화면이 scene, show, hide 문을 사용한 뒤의 모습으로 바뀌게 됩니다.

label start:
    scene bg uni
    show sylvie smile

    s "아, 안녕, 집까지 같이 갈래?"
    m "그래..."
    "내 목소리는 이미 떨리고 있었다."

    scene bg meadow
    with fade

    "우리는 동네 밖 초원까지 다다랐다."
    "이 곳의 가을은 정말 아름다웠다."
    "어렸을 때 우린 종종 이 곳에서 놀곤 했다."
    m "저기... 음..."

    show sylvie smile
    with dissolve

    "그녀는 나를 향해 돌아섰고 웃어보였다."
    "나는 그녀에게 물었다..."
    m  "음... 너..."
    m "너 내 비주얼 노벨의 원화가가 되어줄래?"

with문은 사용할 트랜지션의 이름을 받습니다. 가장 일반적인 트랜지션은 dissolve 로, 화면이 다음 화면으로 부드럽게 넘어가게 합니다. 또 다른 유용한 트랜지션은 fade 로, 화면을 검은 색으로 사라지게 한 다음, 검은 화면에서 새 화면이 서서히 나타나게 합니다.

트랜지션이 여러 개의 scene, show, hide 문 뒤에 나오면, 트랜지션이 각 명령문에 한꺼번에 적용됩니다. 다음과 같이 적으면:

    scene bg meadow
    show sylvie smile
    with dissolve

"bg meadow" 와 "sylvie smiles" 두 이미지 모두 동시에 디졸브될 것입니다. 한 번에 하나씩 디졸브 효과를 적용하고 싶다면 두 개의 with 문을 사용해야 합니다:

    scene bg meadow
    with dissolve
    show sylvie smile
    with dissolve

이렇게 하면 meadow를 맨 처음 디졸브하고, 그 다음에 sylvie를 디졸브합니다. meadow를 즉시 나타나게 하고 그 다음에 sylvie를 나타내고 싶다면 아래와 같이 적으면 됩니다.

    scene bg meadow
    with None
    show sylvie smile
    with dissolve

여기에서 None은 실제로 사용자에게 아무것도 보여주지 않은 채, 이전 화면이 무엇이었는지에 대한 렌파이의 개념을 업데이트하는 특수한 트랜지션을 가리킵니다.

위치

기본적으로 그림들은 가로방향의 가운데 지점에 나타나며, 그림의 밑변이 화면의 밑변에 닿게 됩니다. 이 위치는 배경그림과 하나의 캐릭터만 표시할 때는 적절하겠지만, 화면상에 캐릭터를 여러 명 표시할 때에는 캐릭터를 다른 위치에 표시해야 할 것입니다. 연출을 위해 캐릭터를 재배치할 때도 마찬가지일 것입니다.

     show sylvie smile at right

위치를 재정렬하려면 show문에 at절을 추가하세요. at절은 위치를 입력 받으며, 이미지를 at절에 적힌 위치에 표시합니다. 렌파이에서는 미리 정의되어있는 몇 가지 위치들을 사용할 수 있습니다. 화면 좌측을 가리키는 left, 화면 우측을 가리키는 right, 가로방향의 중간 지점인 center (기본값), 가로 방향과 세로 방향의 중심부인 truecenter 입니다.

사용자는 새로운 위치나 복잡한 이동 이벤트를 지정할 수도 있습니다만, 퀵스타트 매뉴얼에서 다루지는 않겠습니다.

음악과 효과음

대부분의 게임에는 배경 음악이 있습니다. 렌파이에서 음악은 play music 문으로 재생할 수 있습니다. 이 명령문 다음에 파일 이름이 적힌 문자열을 적거나, 재생할 파일 이름 리스트를 적을 수 있습니다. 리스트를 적으면, 리스트에 적힌 순서대로 파일을 재생합니다.:

    play music "illurock.ogg"
    play music ["1.ogg", "2.ogg"]

음악을 변경할 때에는 fadeout 절을 넣어, 새 음악이 재생되기 전에 이전 음악을 페이드아웃 할 수도 있습니다.

    play music "illurock.ogg" fadeout 1.0

loop절을 적으면, 음악을 반복 재생합니다. noloop 절을 적으면 반복재생하지 않습니다. 렌파이에서 음악 파일은 사용자가 중지시키기 전까지 자동으로 반복재생됩니다.

    play music "illurock.ogg" loop
    play music "illurock.ogg" noloop

음악 재생은 stop music 문은 중지시킵니다. fadeout 절을 입력할 수도 있습니다.

    stop music

효과음은 play sound 문으로 재생할 수 있습니다. 이 명령문은 음악을 반복재생하지 않습니다.

    play sound "effect.ogg"

play sound문에는 play music문과 동일한 절을 입력할 수 있습니다.

렌파이는 많은 종류의 효과음, 음악 파일 포맷을 지원하지만, OGG Vorbis를 선호합니다. 그림 파일과 마찬가지로, 효과음과 음악 파일은 반드시 game 디렉토리 안에 있어야 합니다.

pause문

pause문은 사용자가 마우스를 클릭할 때까지 렌파이를 일시정지하는 명령문입니다. 표현식을 추가로 입력하면, 표현식을 숫자로 계산해 해당 숫자만큼의 초가 경과했을 때 일시정지를 자동으로 해제합니다.

게임 끝내기

return 문을 이용하면 아무것도 호출하지 않고도 게임을 종료시킬 수 있습니다. 그 전에 플레이어에게 게임이 끝났음을 알려주는 엔딩 이름이나 엔딩 숫자를 넣는 것이 좋겠습니다.

    ".:. 굿 엔딩."

    return

이것이 선택지가 없는 게임인 키네틱 노벨을 만들 때 필요한 전부입니다. 이제, 플레이어에게 선택지를 표시하는 게임을 만들 때 필요한 것이 무엇인지를 살펴보겠습니다.

선택지, 레이블, 점프

menu문을 사용하면 유저에게 선택지를 표시할 수 있습니다:

    s "물론이지, 근데 \"비주얼 노벨\"이 뭐야?"

menu:
    "그림이 있는 이야기야.":
        jump vn

    "야한 게임이야.":
        jump hentai

label vn:
    m "그림와 음악이 함께 있는 이야기야."
    jump marry

label hentai:
    m "섹스를 많이 하는 게임이야."
    jump marry

label marry:
    scene black
    with dissolve

    "--- 몇 년 후 ---"

이 예제에는 렌파이에서 선택지를 사용하는 법이 나와있습니다. menu문은 게임 내에 선택지를 표시합니다. menu문은 행으로 이루어진 하나의 블럭을 입력 받는데, 각 행에는 문자열 뒤에 콜론이 붙게 됩니다. 이것이 플레이어에게는 선택지로 나타납니다. 각 선택지 다음 줄에는 하나 이상의 렌파이 명령문을 적어야 합니다. 선택지 하나가 선택되면 그 다음줄에 있는 명령문들이 실행됩니다.

위의 예제에서 각 선택지는 jump 문을 실행합니다. jump문은 label문으로 정의된 레이블로 제어 흐름을 이동시킵니다. 해당 레이블 다음에 적힌 코드들이 실행됩니다.

예제에서 실비가 질문을 마치고 난 후, 플레이어는 두 개의 선택지를 보게 됩니다. 플레이어가 "그림이 있는 이야기야."를 선택하면 첫 번째 jump문이 실행되고, 제어 흐름은 vn 레이블로 이동합니다. 이렇게 되면 주인공 캐릭터가 "그림와 음악이 함께 있는 이야기야."라고 말한 뒤 제어 흐름이 marry 레이블로 이동합니다.

레이블은 게임 디렉토리 안에 있고 .rpy로 끝나는 모든 파일 안에 정의할 수 있습니다. 렌파이는 그 레이블이 포함되어 있는 파일이라면 파일 이름은 신경쓰지 않습니다. 레이블은 하나의 파일 안에만 존재할 수도 있습니다.

파이썬과 if문

간단한 (혹은 다소 복잡한)게임이라면 오직 menu와 jump문만을 사용하여 만들 수 있지만, 이후에는 플레이어의 선택을 변수에 저장하여 나중에 그것을 이용해야 하는 경우가 있습니다. 이 때문에 렌파이에서는 파이썬을 지원합니다.

파이썬의 능력은 두 가지 방법으로 활용할 수 있습니다. $ 기호로 시작하는 하나의 행은 단행 파이썬 명령문이며, "python:" 키워드는 파이썬 명령문의 블럭을 열 때 사용합니다.

파이썬을 이용하면 사용자의 입력에 따라 플래그를 간단히 저장할 수 있습니다. 게임의 시작 부분에 플래그를 초기화하면:

label start:
    $ bl_game = False

선택지로 선택된 코드 안에서 플래그를 바꿀 수 있습니다.

label hentai:

    $ bl_game = True

    m "섹스를 많이 하는 게임이야."
    s "그럼 BL 게임같은 거 말하는 거야?"
    s "나 그런 거 진짜 만들고 싶었는데."
    s "지금 당장 시작해야지!"

    jump marry

그리고 나중에 확인할 수 있습니다.:

"그리고 우리는 비주얼 노벨 제작팀이 되었다."
"우리는 게임들을 만들면서 아주 즐겁게 지냈다."

if bl_game:
    "뭐, 그녀가 만들자고 우겼던 BL게임은 논외라고 치자."

"그러던 어느 날..."

물론 파이썬 변수에는 True/False 값 외에 여러가지 값을 저장할 수 있습니다. 파이썬에서 활용할 수 있는 값이라면 무엇이든 가능합니다. 플레이어의 이름을 저장하거나, 포인트를 저장하거나, 혹은 다른 목적으로도 활용할 수 있습니다. 렌파이에는 모든 파이썬 프로그래밍 언어를 사용할 수 있는 능력이 있어 많은 것을 해볼 수 있습니다.

게임 배포하기

게임을 완성했다면, 게임을 배포하기 전에 해야 할 일이 몇 가지 있습니다:

options.rpy 수정하기.

새로운 게임 프로젝트를 만들 때 생성되는 options.rpy 에는 수정해야 할만한 몇 가지 설정이 들어 있습니다. 스크린 가로 길이, 스크린 세로 길이 같은 몇 가지 설정은 게임을 만들기 전에 설정되어야 할 것입니다. 윈도우 제목 같은 것들은 언제라도 설정할 수 있습니다.

렌파이로 제작되었음을 알리는 문구 넣기.

이 단계는 선택사항이지만, 크레딧을 만들고 싶다면 그 안에 렌파이를 언급해주시면 감사하겠습니다. "비주얼 노블 엔진 렌파이로 제작됨" 같은 문구가 입력되었으면 하지만 어디까지나 제안일 뿐, 어떻게 입력할 지는 여러분 마음입니다.

여러분께서 만드는 게임은 렌파이를 홍보하는 가장 좋은 방법이라고 생각하며, 이 문구가 다른 사람들에게 렌파이로 비주얼 노벨을 만드는 방법을 배우는 데에 도움이 되길 바랍니다.

렌파이 최신 버전 확인하기.

렌파이의 새 버전은 버그를 고치고 새로운 기능들을 추가하기 위해 정기적으로 배포됩니다. 게임을 배포하기 전에 런처에서 "업데이트"를 눌러 렌파이를 최신버전으로 업데이트하세요. http://www.renpy.org/latest.html 에서 렌파이의 최신 버전을 다운받거나 수정 사항을 확인할 수 있습니다.

스크립트 확인하기.

렌파이 런처에서 Tools 메뉴를 클릭한 후, "스크립트 확인 (오류 검사)"를 선택하세요. 여러분의 게임이 특정 사용자들에게 영향을 미칠 수 있는 몇 가지 오류를 확인할 것입니다. 이러한 오류들은 Mac과 Linux 사용자들에게 영향을 미칠 수도 있으므로 여러분의 컴퓨터에서 발견할 수 없는 것이라 하더라도 모두 수정해야 합니다.

배포판 만들기.

런처의 첫 번째 페이지에서 "배포판 만들기"를 선택하세요. options.rpy 에 포함된 정보를 기반으로 런처가 당신의 게임을 포함한 하나 이상의 아카이브 파일을 만들 것입니다.

테스트.

"오류 검사" 메뉴로는 테스트를 대체할 수 없습니다. 배포하기 전에 게임을 확인하는 것은 당신의 의무입니다. 친구들에게 베타테스트를 부탁해보세요. 테스터는 제작자가 발견할 수 없는 문제들을 자주 발견합니다.

배포.

(Windows, Mac, Linux 용으로) 만든 파일을 웹 상에 올리고 사람들에게 게임을 받으라고 얘기하세요. 축하드립니다, 마침내 게임을 내놓게 되었군요.

렌파이로 제작된 게임을 살펴볼 수 있도록 게임 데이터베이스 에 게임을 추가해주시면 감사하겠습니다.

The Question 스크립트

The Question 스크립트는 이곳 에서 보실 수 있습니다.

이제부터 무엇을 해야 하나요?

퀵스타트 매뉴얼에서는 렌파이의 능력을 겉만 훑어봤습니다. 매뉴얼을 간단하게 만들기 위해 렌파이에서 지원하는 많은 기능을 생략했습니다. 렌파이의 능력이 어떤지 감을 잡으려면 길라잡이를 플레이해서 에일린이 렌파이의 기능을 시연하는 것을 살펴보시기 바랍니다.

렌파이의 완벽한 가이드 역할을 하는 이 매뉴얼의 나머지 (복잡한) 부분도 읽어보시기 바랍니다.

렌파이 공식 홈페이지에는, 자주 올라오는 질문들에 대한 답변이 적힌 FAQ 와 유용한 코드를 제공하는 쿡북 이 있습니다. 궁금한 점이 있으시다면 렌파이 공식 포럼인 렘마 소프트 포럼 에 질문을 하세요. 이 포럼은 렌파이 커뮤니티의 중심이며, 새로운 사용자와 질문을 환영합니다.

비주얼 노벨 엔진 렌파이를 선택해주셔서 감사합니다. 여러분이 렌파이로 만든 게임을 기대할게요!