NVL버전 The Question

렌파이에서 "The Question" 프로젝트가 저장된 폴더를 열어, script.rpy 파일에 들어있는 스크립트를 아래에 나와있는 코드로 바꾸면 됩니다. 이 스크립트에서 대사창 배경으로 사용하는 nvl_window.png 파일은 여기 에서 내려받을 수 있습니다.

# 게임에서 사용하는 이미지를 선언한다.
image bg lecturehall = "lecturehall.jpg"
image bg uni = "uni.jpg"
image bg meadow = "meadow.jpg"
image bg club = "club.jpg"

image sylvie normal = "sylvie_normal.png"
image sylvie giggle = "sylvie_giggle.png"
image sylvie smile = "sylvie_smile.png"
image sylvie surprised = "sylvie_surprised.png"

image sylvie2 normal = "sylvie2_normal.png"
image sylvie2 giggle = "sylvie2_giggle.png"
image sylvie2 smile = "sylvie2_smile.png"
image sylvie2 surprised = "sylvie2_surprised.png"

# Declare characters
define s = Character(None, kind=nvl, what_prefix="\"", what_suffix="\"",
                     what_color="#c8ffc8")
define m = Character(None, kind=nvl, what_prefix="\"", what_suffix="\"",
                     what_color="#ffc8c8")
define narrator = Character(None, kind=nvl)

# NVL 설정
init python:
    menu = nvl_menu

    # 마우스 커서가 올라가지 않은 선택문 색상.
    style.nvl_menu_choice.idle_color = "#ccccccff"

    # 마우스 커서가 올라간 선택문 색상.
    style.nvl_menu_choice.hover_color = "#ffffffff"

    # 마우스 커서가 올라가지 않은 선택문의
    # 바탕색.
    style.nvl_menu_choice_button.idle_background = "#00000000"

    # 마우스 커서가 올라간 선택문의
    # 바탕색.
    style.nvl_menu_choice_button.hover_background = "#ff000044"

    # 선택문을 들여쓰기할 간격.
    style.nvl_menu_choice_button.left_margin = 20


    style.nvl_window.background = "nvl_window.png"
    style.nvl_window.xpadding = 55
    style.nvl_window.ypadding = 55

    config.empty_window = nvl_show_core
    config.window_hide_transition = dissolve
    config.window_show_transition = dissolve


# 게임은 여기에서부터 시작합니다.
label start:

    $ bl_game = False

    play music "illurock.ogg"

    scene bg lecturehall
    with fade

    window show

    "뭐, 아이린 교수님의 강의는 흥미롭긴 했지만 솔직히 말해서,
     난 그다지 집중할 수가 없었다."

    "마음 속에 너무나 많은 생각들이 있었고, 그 생각들은 결국 하나의 질문으로
    향하고 있었다."

    "내가 누군가에게 물어보려고 했던 하나의 질문."

    window hide
    nvl clear

    scene bg uni
    with fade
    window show

    "학교 밖으로 나왔을 때, 그녀를 보았다."

    window hide
    show sylvie normal
    with dissolve
    window show

    "그녀는 멋진 사람이었다. 그녀를 어렸을 때부터 알고 지냈고
    그녀는 언제나 좋은 친구로 있어주었다."

    "그런데... 요즘 들어... 내 생각에는..."
    "내가 특별한 것을 바라는 것 같다."

    "단지 대화하는 것보다 특별한 것... 수업이 끝나고 같이 집에 걸어가는 것보다
    특별한 무언가를..."

    menu:
        "그래서 결심했다..."

        "... 지금 그녀에게 물어보자.":

            jump rightaway

        "... 나중에 물어보자.":

            jump later


label rightaway:

    nvl clear

    show sylvie smile

    s "아, 안녕, 집까지 같이 갈래?"
    m "그래..."
    "내 목소리는 벌써부터 떨리고 있었다."

    nvl clear

    window hide
    scene bg meadow
    with fade
    window show

    "우리는 동네 밖 초원까지 다다랐다. 이 곳의 가을은
    정말 아름다웠다."
    "어렸을 때 우린 종종 이 곳에서 놀았었지."

    m "저기... 음..."

    window hide
    show sylvie smile
    with dissolve
    window show

    "그녀는 나를 향해 돌아섰고 웃어보였다."
    "나는 그녀에게 물었다...."
    m  "음... 너..."
    m "너 내 비주얼 노벨의 원화가가 되어줄래?"

    show sylvie surprised

    nvl clear

    "침묵."
    "그녀는 놀랐다. 그리고..."

    show sylvie smile

    s "물론이지, 근데 \"비주얼 노벨\"이 뭐야?"

    menu:

        "그림이 있는 이야기야.":
            jump vn

        "야한 게임이야.":
            jump hentai

label vn:

    nvl clear

    m "그림와 음악이 함께 있는 이야기야. 그리고 선택지를 골라서
    이야기 흐름에 영향을 줄 수 있어."
    s "그러니까 어드벤처 책 같은 거야?"
    m "맞아! 짧은 로맨스 소설을 만들까 생각중이야. 그래서
    네가 날 도와줄 수 있을 거라고 생각했어.. 네 그림솜씨 알고 있으니까."

    show sylvie normal

    s "음, 한번 해볼게. 네가 실망하지 않았음 좋겠다."
    m "내가 너한테 실망할 리 없잖아."

    jump marry

label hentai:

    nvl clear

    $ bl_game = True

    m "섹스를 많이 하는 게임이야."
    s "그럼 BL 게임같은 거 말하는 거야? 나 전부터 진짜 만들고
    싶었는데. 지금 당장 시작해야지!"

    hide sylvie
    with dissolve

    "..."

    m "이게 아닌데."

    jump marry

label marry:

    window hide
    nvl clear

    scene black
    with dissolve

    "--- 몇 년 후---"

    nvl clear

    scene bg club
    with dissolve
    window show

    "그리고 우리는 비주얼 노벨 제작팀이 되었다. 우리는 게임들을 만들면서
    아주 즐겁게 지냈다."

    if bl_game:
        "뭐, 그녀가 만드려고 고집했던 BL게임은 논외라고 치자."

    window hide
    nvl clear

    show sylvie2 normal
    with dissolve
    window show

    "그러던 어느 날, 그녀가 내게 물었다..."

    s "저기..."
    m "응?"

    show sylvie2 giggle

    s "결혼하자!"
    m "뭐???"

    show sylvie2 surprised

    s "... 나 사랑하지 않아?"
    m "사랑해, 정말로."

    nvl clear
    show sylvie2 smile

    s "그치? 우리 그동안 로맨틱 비주얼 노벨을 만들고, 함께 시간을 보내고,
    서로를 도왔잖아... 다른 사람에게 사랑을 주면,
    그 사랑이 네게도 온다고."
    m "흠, 그거 멋진 발상이네."

    show sylvie2 giggle

    s "방금 전에 생각난 거야."
    m "어쨌든 멋져."

    nvl clear
    show sylvie2 normal

    s "나도 알아. 그러니까, 나랑 결혼해줄래?"
    m "으음, 물론이지. 사실 원래 그걸 물어보려고 했었는데,
    네가 그 얘길 꺼내서..."
    s "알아. 근데 너 너무 우유부단해서,
    내가 먼저 말 꺼내야겠다고 생각했어."
    m "내 생각엔... 적절한 질문을
    적절한 타이밍에 해야 하는 것 같아."

    show sylvie2 giggle

    s "맞아. 그치만 지금은 토론은 그만두고 나한테 키스해줘!"

    nvl clear
    window hide
    scene black
    with dissolve

    "그 후로 얼마 안 있어서 그녀와 나는 결혼했다. 우리는 그 뒤로 많은
    비주얼 노벨을 만들었다. 그리고 서로 함께  행복하게 살았다."

    ".:. 굿 엔딩."

    return

label later:

    nvl clear
    window hide

    scene black
    with dissolve

    "그래서 나는 그녀에게 나중에 묻기로 결정했다."
    "하지만 내가 우유부단했던 거다."
    "그날 그녀에게 물을 수도 없었고, 나중에 물을 수도 없었다."
    "그녀의 대답은 영영 알 수 없을 것 같다."

    ".:. 배드 엔딩."

    return